6a1f6ee1f8
* lisp/ox.el (org-export-table-dimensions): * lisp/ox-texinfo.el (org-texinfo-template): * lisp/ox-md.el (org-md-link): * lisp/ox-icalendar.el (org-icalendar-use-UTC-date-time-p): * lisp/ox-ascii.el (org-ascii-fixed-width): * lisp/org.el (org-context): * lisp/org-table.el (org-table-eval-formula) (org-table-export): * lisp/org-refile.el: * lisp/org-plot.el (org-plot/gnuplot-to-grid-data): * lisp/org-num.el (org-num): * lisp/org-mouse.el (org-mouse-popup-global-menu) (org-mouse-context-menu): * lisp/org-macro.el (org-macro): * lisp/org-lint.el (org-lint): * lisp/org-keys.el (org-keys): * lisp/org-duration.el: * lisp/org-clock.el (org-clock-get-last-clock-out-time) (org-clock-update-mode-line, org-find-open-clocks): * lisp/org-agenda.el (org-diary) (org-agenda-check-for-timestamp-as-reason-to-ignore-todo-item) (org-agenda-highlight-todo, org-cmp-alpha) (org-agenda-filter-by-category): * lisp/ol.el (org-link-expand-abbrev, ol): * lisp/ol-docview.el (ol-docview): * lisp/ol-bibtex.el (org-execute-file-search-in-bibtex) (org-bibtex, org-bibtex-read): * lisp/ol-bbdb.el (org-bbdb-anniversary-description): * lisp/ob-tangle.el (org-babel-tangle-jump-to-org): * lisp/ob-table.el (org-babel-table-truncate-at-newline): * lisp/ob-stan.el: * lisp/ob-sqlite.el (org-babel-sqlite-table-or-scalar): * lisp/ob-sql.el: * lisp/ob-shen.el: * lisp/ob-shell.el (org-babel-prep-session:shell) (org-babel-prep-session:shell): * lisp/ob-sed.el (org-babel-execute:sed) (org-babel-execute:sed): * lisp/ob-screen.el: * lisp/ob-sass.el: * lisp/ob-ruby.el (org-babel-prep-session:ruby) (org-babel-prep-session:ruby): * lisp/ob-ref.el (org-babel-ref-resolve, ob-ref): * lisp/ob-python.el (org-babel-prep-session:python) (org-babel-prep-session:python): * lisp/ob-plantuml.el: * lisp/ob-picolisp.el: * lisp/ob-perl.el: * lisp/ob-org.el: * lisp/ob-octave.el (org-babel-prep-session:octave) (org-babel-prep-session:octave) (org-babel-octave-evaluate-session): * lisp/ob-ocaml.el: * lisp/ob-mscgen.el (org-babel-execute:mscgen) (org-babel-execute:mscgen): * lisp/ob-maxima.el: (ob-maxima): * lisp/ob-matlab.el: * lisp/ob-makefile.el: * lisp/ob-lua.el (org-babel-prep-session:lua) (org-babel-prep-session:lua): * lisp/ob-lisp.el: * lisp/ob-ledger.el: * lisp/ob-latex.el (org-babel-expand-body:latex) (org-babel-expand-body:latex, ob-latex): * lisp/ob-js.el: * lisp/ob-java.el: * lisp/ob-io.el (org-babel-prep-session:io) (org-babel-prep-session:io): * lisp/ob-hledger.el: * lisp/ob-haskell.el: * lisp/ob-groovy.el (org-babel-groovy-wrapper-method) (org-babel-groovy-evaluate): * lisp/ob-gnuplot.el: * lisp/ob-fortran.el (org-babel-expand-body:fortran) (org-babel-expand-body:fortran): * lisp/ob-forth.el (org-babel-forth-session-execute): * lisp/ob-exp.el (ob-exp): * lisp/ob-eval.el: * lisp/ob-emacs-lisp.el: * lisp/ob-ebnf.el: * lisp/ob-dot.el: * lisp/ob-ditaa.el: * lisp/ob-css.el: * lisp/ob-core.el (org-babel-put-rownames): * lisp/ob-coq.el: * lisp/ob-comint.el: * lisp/ob-calc.el: * lisp/ob-awk.el: * lisp/ob-asymptote.el: * lisp/ob-abc.el: * lisp/ob-R.el (org-babel-prep-session:R): Formatting fixes.
155 lines
5.2 KiB
EmacsLisp
155 lines
5.2 KiB
EmacsLisp
;;; ob-perl.el --- Babel Functions for Perl -*- lexical-binding: t; -*-
|
|
|
|
;; Copyright (C) 2009-2020 Free Software Foundation, Inc.
|
|
|
|
;; Authors: Dan Davison
|
|
;; Eric Schulte
|
|
;; Keywords: literate programming, reproducible research
|
|
;; Homepage: https://orgmode.org
|
|
|
|
;; This file is part of GNU Emacs.
|
|
|
|
;; GNU Emacs is free software: you can redistribute it and/or modify
|
|
;; it under the terms of the GNU General Public License as published by
|
|
;; the Free Software Foundation, either version 3 of the License, or
|
|
;; (at your option) any later version.
|
|
|
|
;; GNU Emacs is distributed in the hope that it will be useful,
|
|
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
;; GNU General Public License for more details.
|
|
|
|
;; You should have received a copy of the GNU General Public License
|
|
;; along with GNU Emacs. If not, see <https://www.gnu.org/licenses/>.
|
|
|
|
;;; Commentary:
|
|
|
|
;; Org-Babel support for evaluating perl source code.
|
|
|
|
;;; Code:
|
|
(require 'ob)
|
|
|
|
(defvar org-babel-tangle-lang-exts)
|
|
(add-to-list 'org-babel-tangle-lang-exts '("perl" . "pl"))
|
|
|
|
(defvar org-babel-default-header-args:perl '())
|
|
|
|
(defvar org-babel-perl-command "perl"
|
|
"Name of command to use for executing perl code.")
|
|
|
|
(defun org-babel-execute:perl (body params)
|
|
"Execute a block of Perl code with Babel.
|
|
This function is called by `org-babel-execute-src-block'."
|
|
(let* ((session (cdr (assq :session params)))
|
|
(result-params (cdr (assq :result-params params)))
|
|
(result-type (cdr (assq :result-type params)))
|
|
(full-body (org-babel-expand-body:generic
|
|
body params (org-babel-variable-assignments:perl params)))
|
|
(session (org-babel-perl-initiate-session session)))
|
|
(org-babel-reassemble-table
|
|
(org-babel-perl-evaluate session full-body result-type result-params)
|
|
(org-babel-pick-name
|
|
(cdr (assq :colname-names params)) (cdr (assq :colnames params)))
|
|
(org-babel-pick-name
|
|
(cdr (assq :rowname-names params)) (cdr (assq :rownames params))))))
|
|
|
|
(defun org-babel-prep-session:perl (_session _params)
|
|
"Prepare SESSION according to the header arguments in PARAMS."
|
|
(error "Sessions are not supported for Perl"))
|
|
|
|
(defun org-babel-variable-assignments:perl (params)
|
|
"Return list of perl statements assigning the block's variables."
|
|
(mapcar
|
|
(lambda (pair)
|
|
(org-babel-perl--var-to-perl (cdr pair) (car pair)))
|
|
(org-babel--get-vars params)))
|
|
|
|
;; helper functions
|
|
|
|
(defvar org-babel-perl-var-wrap "q(%s)"
|
|
"Wrapper for variables inserted into Perl code.")
|
|
|
|
(defvar org-babel-perl--lvl)
|
|
(defun org-babel-perl--var-to-perl (var &optional varn)
|
|
"Convert an elisp value to a perl variable.
|
|
The elisp value, VAR, is converted to a string of perl source code
|
|
specifying a var of the same value."
|
|
(if varn
|
|
(let ((org-babel-perl--lvl 0) (lvar (listp var)))
|
|
(concat "my $" (symbol-name varn) "=" (when lvar "\n")
|
|
(org-babel-perl--var-to-perl var)
|
|
";\n"))
|
|
(let ((prefix (make-string (* 2 org-babel-perl--lvl) ?\ )))
|
|
(concat prefix
|
|
(if (listp var)
|
|
(let ((org-babel-perl--lvl (1+ org-babel-perl--lvl)))
|
|
(concat "[\n"
|
|
(mapconcat #'org-babel-perl--var-to-perl var "")
|
|
prefix "]"))
|
|
(format "q(%s)" var))
|
|
(unless (zerop org-babel-perl--lvl) ",\n")))))
|
|
|
|
(defvar org-babel-perl-buffers '(:default . nil))
|
|
|
|
(defun org-babel-perl-initiate-session (&optional _session _params)
|
|
"Return nil because sessions are not supported by perl."
|
|
nil)
|
|
|
|
(defvar org-babel-perl-wrapper-method "{
|
|
my $babel_sub = sub {
|
|
%s
|
|
};
|
|
open my $BOH, qq(>%s) or die qq(Perl: Could not open output file.$/);
|
|
my $rv = &$babel_sub();
|
|
my $rt = ref $rv;
|
|
select $BOH;
|
|
if (qq(ARRAY) eq $rt) {
|
|
local $\\=$/;
|
|
local $,=qq(\t);
|
|
foreach my $rv ( @$rv ) {
|
|
my $rt = ref $rv;
|
|
if (qq(ARRAY) eq $rt) {
|
|
print @$rv;
|
|
} else {
|
|
print $rv;
|
|
}
|
|
}
|
|
} else {
|
|
print $rv;
|
|
}
|
|
}")
|
|
|
|
(defvar org-babel-perl-preface nil)
|
|
|
|
(defvar org-babel-perl-pp-wrapper-method
|
|
nil)
|
|
|
|
(defun org-babel-perl-evaluate (session ibody &optional result-type result-params)
|
|
"Pass BODY to the Perl process in SESSION.
|
|
If RESULT-TYPE equals `output' then return a list of the outputs
|
|
of the statements in BODY, if RESULT-TYPE equals `value' then
|
|
return the value of the last statement in BODY, as elisp."
|
|
(when session (error "Sessions are not supported for Perl"))
|
|
(let* ((body (concat org-babel-perl-preface ibody))
|
|
(tmp-file (org-babel-temp-file "perl-"))
|
|
(tmp-babel-file (org-babel-process-file-name
|
|
tmp-file 'noquote)))
|
|
(let ((results
|
|
(pcase result-type
|
|
(`output
|
|
(with-temp-file tmp-file
|
|
(insert
|
|
(org-babel-eval org-babel-perl-command body))
|
|
(buffer-string)))
|
|
(`value
|
|
(org-babel-eval org-babel-perl-command
|
|
(format org-babel-perl-wrapper-method
|
|
body tmp-babel-file))))))
|
|
(when results
|
|
(org-babel-result-cond result-params
|
|
(org-babel-eval-read-file tmp-file)
|
|
(org-babel-import-elisp-from-file tmp-file '(16)))))))
|
|
|
|
(provide 'ob-perl)
|
|
|
|
;;; ob-perl.el ends here
|