6a1f6ee1f8
* lisp/ox.el (org-export-table-dimensions): * lisp/ox-texinfo.el (org-texinfo-template): * lisp/ox-md.el (org-md-link): * lisp/ox-icalendar.el (org-icalendar-use-UTC-date-time-p): * lisp/ox-ascii.el (org-ascii-fixed-width): * lisp/org.el (org-context): * lisp/org-table.el (org-table-eval-formula) (org-table-export): * lisp/org-refile.el: * lisp/org-plot.el (org-plot/gnuplot-to-grid-data): * lisp/org-num.el (org-num): * lisp/org-mouse.el (org-mouse-popup-global-menu) (org-mouse-context-menu): * lisp/org-macro.el (org-macro): * lisp/org-lint.el (org-lint): * lisp/org-keys.el (org-keys): * lisp/org-duration.el: * lisp/org-clock.el (org-clock-get-last-clock-out-time) (org-clock-update-mode-line, org-find-open-clocks): * lisp/org-agenda.el (org-diary) (org-agenda-check-for-timestamp-as-reason-to-ignore-todo-item) (org-agenda-highlight-todo, org-cmp-alpha) (org-agenda-filter-by-category): * lisp/ol.el (org-link-expand-abbrev, ol): * lisp/ol-docview.el (ol-docview): * lisp/ol-bibtex.el (org-execute-file-search-in-bibtex) (org-bibtex, org-bibtex-read): * lisp/ol-bbdb.el (org-bbdb-anniversary-description): * lisp/ob-tangle.el (org-babel-tangle-jump-to-org): * lisp/ob-table.el (org-babel-table-truncate-at-newline): * lisp/ob-stan.el: * lisp/ob-sqlite.el (org-babel-sqlite-table-or-scalar): * lisp/ob-sql.el: * lisp/ob-shen.el: * lisp/ob-shell.el (org-babel-prep-session:shell) (org-babel-prep-session:shell): * lisp/ob-sed.el (org-babel-execute:sed) (org-babel-execute:sed): * lisp/ob-screen.el: * lisp/ob-sass.el: * lisp/ob-ruby.el (org-babel-prep-session:ruby) (org-babel-prep-session:ruby): * lisp/ob-ref.el (org-babel-ref-resolve, ob-ref): * lisp/ob-python.el (org-babel-prep-session:python) (org-babel-prep-session:python): * lisp/ob-plantuml.el: * lisp/ob-picolisp.el: * lisp/ob-perl.el: * lisp/ob-org.el: * lisp/ob-octave.el (org-babel-prep-session:octave) (org-babel-prep-session:octave) (org-babel-octave-evaluate-session): * lisp/ob-ocaml.el: * lisp/ob-mscgen.el (org-babel-execute:mscgen) (org-babel-execute:mscgen): * lisp/ob-maxima.el: (ob-maxima): * lisp/ob-matlab.el: * lisp/ob-makefile.el: * lisp/ob-lua.el (org-babel-prep-session:lua) (org-babel-prep-session:lua): * lisp/ob-lisp.el: * lisp/ob-ledger.el: * lisp/ob-latex.el (org-babel-expand-body:latex) (org-babel-expand-body:latex, ob-latex): * lisp/ob-js.el: * lisp/ob-java.el: * lisp/ob-io.el (org-babel-prep-session:io) (org-babel-prep-session:io): * lisp/ob-hledger.el: * lisp/ob-haskell.el: * lisp/ob-groovy.el (org-babel-groovy-wrapper-method) (org-babel-groovy-evaluate): * lisp/ob-gnuplot.el: * lisp/ob-fortran.el (org-babel-expand-body:fortran) (org-babel-expand-body:fortran): * lisp/ob-forth.el (org-babel-forth-session-execute): * lisp/ob-exp.el (ob-exp): * lisp/ob-eval.el: * lisp/ob-emacs-lisp.el: * lisp/ob-ebnf.el: * lisp/ob-dot.el: * lisp/ob-ditaa.el: * lisp/ob-css.el: * lisp/ob-core.el (org-babel-put-rownames): * lisp/ob-coq.el: * lisp/ob-comint.el: * lisp/ob-calc.el: * lisp/ob-awk.el: * lisp/ob-asymptote.el: * lisp/ob-abc.el: * lisp/ob-R.el (org-babel-prep-session:R): Formatting fixes.
109 lines
3.8 KiB
EmacsLisp
109 lines
3.8 KiB
EmacsLisp
;;; ob-awk.el --- Babel Functions for Awk -*- lexical-binding: t; -*-
|
|
|
|
;; Copyright (C) 2011-2020 Free Software Foundation, Inc.
|
|
|
|
;; Author: Eric Schulte
|
|
;; Keywords: literate programming, reproducible research
|
|
;; Homepage: https://orgmode.org
|
|
|
|
;; This file is part of GNU Emacs.
|
|
|
|
;; GNU Emacs is free software: you can redistribute it and/or modify
|
|
;; it under the terms of the GNU General Public License as published by
|
|
;; the Free Software Foundation, either version 3 of the License, or
|
|
;; (at your option) any later version.
|
|
|
|
;; GNU Emacs is distributed in the hope that it will be useful,
|
|
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
;; GNU General Public License for more details.
|
|
|
|
;; You should have received a copy of the GNU General Public License
|
|
;; along with GNU Emacs. If not, see <https://www.gnu.org/licenses/>.
|
|
|
|
;;; Commentary:
|
|
|
|
;; Babel's awk can use special header argument:
|
|
;;
|
|
;; - :in-file takes a path to a file of data to be processed by awk
|
|
;;
|
|
;; - :stdin takes an Org data or code block reference, the value of
|
|
;; which will be passed to the awk process through STDIN
|
|
|
|
;;; Code:
|
|
(require 'ob)
|
|
(require 'org-compat)
|
|
|
|
(declare-function org-babel-ref-resolve "ob-ref" (ref))
|
|
(declare-function orgtbl-to-generic "org-table" (table params))
|
|
|
|
(defvar org-babel-tangle-lang-exts)
|
|
(add-to-list 'org-babel-tangle-lang-exts '("awk" . "awk"))
|
|
|
|
(defvar org-babel-awk-command "awk"
|
|
"Name of the awk executable command.")
|
|
|
|
(defun org-babel-expand-body:awk (body _params)
|
|
"Expand BODY according to PARAMS, return the expanded body."
|
|
body)
|
|
|
|
(defun org-babel-execute:awk (body params)
|
|
"Execute a block of Awk code with org-babel.
|
|
This function is called by `org-babel-execute-src-block'."
|
|
(message "executing Awk source code block")
|
|
(let* ((result-params (cdr (assq :result-params params)))
|
|
(cmd-line (cdr (assq :cmd-line params)))
|
|
(in-file (cdr (assq :in-file params)))
|
|
(full-body (org-babel-expand-body:awk body params))
|
|
(code-file (let ((file (org-babel-temp-file "awk-")))
|
|
(with-temp-file file (insert full-body)) file))
|
|
(stdin (let ((stdin (cdr (assq :stdin params))))
|
|
(when stdin
|
|
(let ((tmp (org-babel-temp-file "awk-stdin-"))
|
|
(res (org-babel-ref-resolve stdin)))
|
|
(with-temp-file tmp
|
|
(insert (org-babel-awk-var-to-awk res)))
|
|
tmp))))
|
|
(cmd (mapconcat #'identity
|
|
(append
|
|
(list org-babel-awk-command
|
|
"-f" code-file cmd-line)
|
|
(mapcar (lambda (pair)
|
|
(format "-v %s='%s'"
|
|
(car pair)
|
|
(org-babel-awk-var-to-awk
|
|
(cdr pair))))
|
|
(org-babel--get-vars params))
|
|
(list in-file))
|
|
" ")))
|
|
(org-babel-reassemble-table
|
|
(let ((results
|
|
(cond
|
|
(stdin (with-temp-buffer
|
|
(call-process-shell-command cmd stdin (current-buffer))
|
|
(buffer-string)))
|
|
(t (org-babel-eval cmd "")))))
|
|
(when results
|
|
(org-babel-result-cond result-params
|
|
results
|
|
(let ((tmp (org-babel-temp-file "awk-results-")))
|
|
(with-temp-file tmp (insert results))
|
|
(org-babel-import-elisp-from-file tmp)))))
|
|
(org-babel-pick-name
|
|
(cdr (assq :colname-names params)) (cdr (assq :colnames params)))
|
|
(org-babel-pick-name
|
|
(cdr (assq :rowname-names params)) (cdr (assq :rownames params))))))
|
|
|
|
(defun org-babel-awk-var-to-awk (var &optional sep)
|
|
"Return a printed value of VAR suitable for parsing with awk."
|
|
(let ((echo-var (lambda (v) (if (stringp v) v (format "%S" v)))))
|
|
(cond
|
|
((and (listp var) (listp (car var)))
|
|
(orgtbl-to-generic var (list :sep (or sep "\t") :fmt echo-var)))
|
|
((listp var)
|
|
(mapconcat echo-var var "\n"))
|
|
(t (funcall echo-var var)))))
|
|
|
|
(provide 'ob-awk)
|
|
|
|
;;; ob-awk.el ends here
|